Функция string_replace

[vladua100]

Данная функция заменит одну часть строки на другую.

Параметры:
(inputvar[],const searchstring[],const replacestring[],bool:ignorecase=true,bool:replaceall=false)
inputvar[] - строка,в которой вы желаете заменить текст.
searchstring[] - строка,содержащая искомый текст,который вы желаете заменить.
replacestring[] - строка,содержащая текст,которым вы желаете заменить искомый текст.
ignorecase(необязательный параметр) - Когда установлено значение true,то регистр не имеет значения.
replaceall(необязательный параметр) - Когда установлено значение false,то замена пройдет лишь 1 раз.

Значения,возвращаемые функцией:
Возвращает -1, если replacestring содержит searchstring
Возвращает 0, если inputvar не содержит искомого текста
Возвращает 1 при успешном выполнении

Пример использования функции:

public OnGameModeInit()
{
	new name[MAX_PLAYER_NAME];
	name = "_Pawno_Info_";
	string_replace(name, "_", " ", _, true); //заменит все подчеркивания на пробелы
	printf("Name is: %s",name);
	return 1;
}

Сама функция:

string_replace(inputvar[],const searchstring[],const replacestring[],bool:ignorecase=true,bool:replaceall=false)
{
	if(strfind(replacestring,searchstring,ignorecase) != -1) return -1;
	new pos = strfind(inputvar,searchstring,ignorecase);
	if(pos == -1) return 0;
	if(replaceall == true)
	{
		while(strfind(inputvar,searchstring,ignorecase) != -1)
		{
			pos = strfind(inputvar,searchstring,ignorecase);
			strdel(inputvar, pos, pos+strlen(searchstring));
			strins(inputvar, replacestring, pos, strlen(inputvar));
		}
	}
	else
	{
		strdel(inputvar, pos, pos+strlen(searchstring));
		strins(inputvar, replacestring, pos, strlen(inputvar));
	}
	return 1;
}